Excel Right函数和RightB函数使用方法的7个实例，含与Len、Find组合截取长度不一指定字符后的数字

在 Excel 中，Right函数和RightB函数都用于从文本右边第一个字符开始提取指定字符数；但它们有区别，Right函数以字符计，它把全角（如“汉字”）和半角（如“数字和字母”）字符都计作一个字符；RightB函数以字节计，它把全角字符计作两个字节、半角字符计作一个字节。另外，与 Right 和 RightB 函数作用相似的还有 Left、LeftB 与 Mid、MidB 函数。

Right函数和RightB函数常与Len函数和Find函数组合使用，Right + Len + Find 组合可实现从文本右边截取到任意指定字符和截取文本长度不一样的某个指定字符后的所有字符。

一、Excel Right函数和RightB函数的语法

1、 Right函数表达式：RIGHT(Text, [Num_Chars])

中文表达式：RIGHT(文本，[提取字符数])

2、 RightB函数表达式：RIGHTB(Text, [Num_Bytes])

中文表达式：RIGHTB(文本，[提取字节数])

3、说明：

A、Right函数和RightB函数都用于从右边提取指定长度的字符，但二者有区别：Right函数把全角（如“汉字”）和半角（如“数字和字母”）字符都计作 1 个字符；RightB函数把全角字符计作 2 个字节、半角字符计作 1 个字节。

B、Num_Chars 为可选项，如果省略，Right函数默认提取 1 个字符；Num_Chars 必须大于等于 0，否则将返回值错误 #VALUE!；如果Num_Chars 大于文本长度，Right函数将返回所有文本。

C、Num_Bytes 也为可选项，如果省略，RightB函数默认提取 1 个字节；Num_Bytes 必须大于等于 0，否则将返回值错误 #VALUE!；如果Num_Bytes 大于文本总字节数，RightB函数将返回所有文本。

二、Excel Right函数的使用方法及实例

（一）从由数字、字母和汉字组成的文本中提取指定字符的实例

1、双击 B1 单元格，输入公式 =RIGHT(A1,4)，按回车，返回 86.9；选中 B1，把鼠标移到 B1 右下角的单元格填充柄上，鼠标变为加号后，双击左键，则把 A2 和 A3 中的文本也从右边提取 4 个字符；操作过程步骤，如图1所示：

图1

2、公式说明：

A、公式 =RIGHT(A1,4) 中，A1 为要提取字符的文本，4 为提取字符长度，公式的意思是：从 A1 的右边第 1 个字符开始提取 4 个字符，恰好提取到 86.9。

B、从 A2 中提取 4 个字符的结果为“秋衣35”，说明Right函数把汉字和数字都计作一个字符。

（二）提取字数省略与必须大于等于 0 的实例

1、双击 B1 单元格，把公式 =RIGHT(A1) 复制到 B1，按回车，返回 9；双击 B1，在 A1 后输入逗号（,)，按回车，返回空文本；双击 B1，在逗号后输入 0，按回车，返回空文本；再次双击 B1，把 0 改为 -1，按回车，返回值错误 #VALUE!；操作过程步骤，如图2所示：

图2

2、公式说明：

A、公式 =RIGHT(A1) 省略了提取字符数，默认提取一个字符，因此返回 9。

B、公式 =RIGHT(A1,) 和 =RIGHT(A1,0) 都返回空文本，说明省略提取字符数时，不能在第一个参数后加逗号；若加逗号相当于把提取字符数设置为 0。

C、公式 =RIGHT(A1,-1) 把提取字符数设置为 -1，由于Right函数要求提取字符必须大于等于 0，因此返回值错误。

（三）Right + Len 返回所有文本的实例

1、双击 B1 单元格，把公式 =RIGHT(A1,LEN(A1)) 复制到 B1，按回车，返回 A1 中的所有文本；双击 B1，把 LEN(A1) 改为 LEN(A1)+1，按回车，同样返回 A1 中的所有文本；操作过程步骤，如图3所示：

图3

2、公式说明：

A、公式 =RIGHT(A1,LEN(A1)) 中，先用 LEN(A1) 返回 A1 的文本长度，然后用 Right 从右边截取 A1 中的所有文本。

B、公式 =RIGHT(A1,LEN(A1)+1) 中提取字符数 LEN(A1)+1 大于 A1 的所有文本长度，但只返回 A1 中的所有文本，说明提取字符数大于文本长度时，Right函数仅提取所有文本。

三、Excel RightB函数的使用方法及实例

（一）全角计作 2 个字节与半角计作 1 个字节的实例

1、双击 B1 单元格，把公式 =RIGHTB(A1,6) 复制到 B1，按回车，返回“衫86.9”；操作过程步骤，如图4所示：

图4

2、公式说明：

公式 =RIGHTB(A1,6) 要从右边第 1 个字符开始提取 6 个字节的字符，提取结果为“衫86.9”，共有 5 个字符，其中只有一个汉字，数字和小数点都只占 1 个字节共 4 个字符，说明汉字占两个字节。

（二）RightB + LenB 返回所有文本的实例

1、双击 B1 单元格，把公式 =RIGHTB(A1,LENB(A1)) 复制到 B1，按回车，返回 A1 中的所有文本；双击 B1，把 LENB(A1) 改为 LENB(A1)+2，按回车，也返回 A1 中的所有文本；操作过程步骤，如图5所示：

图5

2、公式说明：

A、公式 =RIGHTB(A1,LENB(A1)) 中，LENB(A1) 用于返回 A1 中所有文本的总字节数，结果为 20；LebB函数也把全角字符计作 2 个字节、半角字符计作 1 个字节；则公式变为 =RIGHTB(A1,20)，最后从右边第一个字符开始返回 20 个字节的文本，即返回 A1 中的所有文本。

B、公式 =RIGHTB(A1,LENB(A1)+2) 中，LENB(A1)+2 大于 A1 中所有文本的总字节数，但仍然仅返回 A1 中所有文本，说明当提取字节数大于所有文本的总字节数时，RightB函数只返回所有文本。之所以加 2，是为了确保提取字节数足够长，即假设多出一个汉字，因为每个汉字占 2 个字节。

四、Excel Right函数和RightB函数的应用实例

（一）Right + Len + Find函数组合实现从右边截取到任意指定字符

1、假如要截取“WS-560长袖白衬衫，红色秋衣”右边的汉字。双击 B1 单元格，把公式 =RIGHT(A1,LEN(A1)-FIND("长",A1)+1) 复制到 B1，按回车，返回“长袖白衬衫，红色秋衣”；操作过程步骤，如图6所示：

图6

2、公式 =RIGHT(A1,LEN(A1)-FIND("长",A1)+1) 说明：

A、FIND("长",A1) 返回“长”字在 A1 中的位置，结果为 7；“长”为要截取汉字部分左起的第一个字符，Find函数把全角和半角都计作一个字符。

B、LEN(A1) 返回 A1 中文本的长度，结果为 16；Len函数也把全角与半角都计作一个字符。

C、LEN(A1)-FIND("长",A1)+1 用于计算要截取的字符数，把上面的值代入后为 16 - 7 + 1，结果为 10，恰好为 9 个汉字加一个逗号。

D、则公式变为 =RIGHT(A1,10)，最后用Right函数从右边第一个字符开始截 10 个字符，恰好截得 A1 中的汉字部分。

另外，也可以用 RightB + LenB + FindB 实现同样功能，公式可以这样写：=RIGHTB(A1,LENB(A1)-FINDB("长",A1)+1)，公式中每个函数都把全角计作 2 个字节、半角计作 1 个字节。

（二）Right + Len + Find函数组合实现截取文本长度不一样的某个指定字符后的所有字符

1、假如要截取 A 列 c 后的所有数字。双击 B2 单元格，把公式 =RIGHT(A2,LEN(A2)-FIND("c",A2)) 复制到 B2，按回车，返回 98643；操作过程步骤，如图7所示：

图7

2、公式 =RIGHT(A2,LEN(A2)-FIND("c",A2)) 说明：

公式与上面的公式 =RIGHT(A1,LEN(A1)-FIND("长",A1)+1) 是一个意思，如果要连 c 一起截取，需要再加 1，即 =RIGHT(A2,LEN(A2)-FIND("c",A2)+1)。

（三）Right + Trim函数组合实现先去掉空格再截取

1、假如要截取的文本有些前面带空格、有些后面带空格和有些不带空格。选中 B2 单元格，输入公式 =RIGHT(A2,5)，按回车，返回 8643；用双击 B2 右下角单元格填充柄的方法返回剩余的截取结果。双击 C2，把公式 =RIGHT(TRIM(A2),5) 复制到 C2，按回车，返回 98643；同样用双击 C2 单击格填充柄的方法返回剩余的截取结果。操作过程步骤，如图8所示：

图8

2、公式说明：

A、公式 =RIGHT(A2,5) 与 =RIGHT(TRIM(A2),5) 的区别为：前者没有先去空格就截取，后者先去空格再截取；因此，对于文本前后有空格的情况，前者会返回不正确的结果，而后者能返回正确结果；例如 B2 中的 8643 少截取了一个 9，而 C2 中的 98643 是正确的结果。

B、TRIM(A2) 用于去掉 A2 中文本前后的空格。