Excel乘法函数Product与*/用于计算乘除法的10个实例，含用一个数乘或除表格的所有数、提价和多数指数运算公

在 Excel 中，计算乘法既可用Product函数又可用星号 *，但它们有区别，Product函数不但能把单个数值作为参数，并且还能把数组和引用单元格作为参数，例如要计算 A1 到 A6 的所有数值的乘积，不需要一个个写，只需写 A1:A6 即可；而用星号只能一个个写。计算除法也有两种方法，一种是用Product函数，另一种是用斜杠（/），它们的区别与计算乘法相同。

在乘除法计算过程中，通常会遇到用一个数乘或除表格的所有数，它们既用可Excel提供的功能即可实现，又可用Excel乘法公式或除法公式实现，它们的区别为：一个在原数据修改，另一个生成新数据。

一、Excel乘法函数Product函数的语法

1、表达式：PRODUCT(Number1, [Number2], ...)

中文表达式：PRODUCT(数字、数组、单元格或单元格区域1, [数字、数组、单元格或单元格区域2], ...)

2、说明：

A、Product函数最多只能有 255 个 Number。

B、如果逻辑值（True 和 False）直接作为Product函数的参数，计算时，True被转为 1，False 被转为 0；如果逻辑值是在数组或引用单元格中，它们将被忽略。

C、如果数组或引用单元格区域包含空格或文本，计算时，它们也被忽略。

二、Excel乘法函数Product函数的使用方法及实例

（一）两列数字相乘的实例

1、假如要求营业额。双击 E2 单元格，把公式 =PRODUCT(C2,D2) 复制到 E2，按回车，返回 13425；选中 E2，把鼠标移到 E2 右下角的单元格填充柄上，鼠标变为加号（+）后，双击左键，则求出剩余的营业额；操作过程步骤，如图1所示：

图1

2、说明：乘法公式 =PRODUCT(C2,D2) 中，C2 和 D2 为引用单元格，意思是把 C2 和 D2 中的数字相乘。

（二）True 和 False 在引用单元格、数组和直接作为参数的不同取值实例

1、选中 B1 单元格，输入公式 =PRODUCT(A1:A3)，按回车，返回 3；双击 B2，把公式 =PRODUCT({3,TRUE,FALSE}) 复制到 B2，按回车，也返回 3；再双击 B3，把公式 =PRODUCT({3,TRUE,FALSE}) 复制到 B3，并把两个大括号去掉，按回车，返回 0；操作过程步骤，如图2所示：

图2

2、公式说明：

A、乘法公式 =PRODUCT(A1:A3) 和 =PRODUCT({3,TRUE,FALSE}) 都返回 3，说明逻辑值（True 和 False）在引用单元格和数组都被忽略。

B、乘法公式 =PRODUCT(3,TRUE,FALSE) 返回 0，说明 True 和 False 直接作为参数时，True 被转为 1、False 被转为 0。

（三）参数为引用单元格区域的实例

1、假如要求 A 和 B 两列数字的乘积。双击 C1 单元格，把公式 =PRODUCT(A1:A5,B1:B5) 复制到 C1，按回车，返回 9.90 ；操作过程步骤，如图3所示：

图3

2、公式说明：

乘法公式 =PRODUCT(A1:A5,B1:B5) 把 A1:A5 和 B1:B5 中的所有数字相乘，即 A1 * A2 * A3 * A4 * A5 * B1 * B2 * B3 * B4 * B5。

三、Excel 用 * 计算乘法的实例

1、同样以求营业额为例。选中 E2 单元格，输入公式 =C2*D2，按回车，返回 13425；再次选中 E2，单击 E2 的单元格填充柄，则返回剩余营业额；操作过程步骤，如图4所示：

图4

2、用 * 计算乘法时，不能这样 =(C2:C7)*(D2:D7) 求两列数字的乘积，这样只能返回 C2 * D2 的乘积。

四、Excel除法的计算方法实例

在 Excel 中，没有提供直接计算除法的函数，除法计算需要用乘法计算函数Product，另外还可以用斜杠（/）计算，以下是它们的计算方法。

（一）用Product函数计算的实例

双击 C1 单元格，把公式 =PRODUCT(A1/B1) 复制到 C1，按回车，返回 20.83；选中 C1，双击 C1 的单元格填充柄，则返回剩余的结果；操作过程步骤，如图5所示：

图5

（二）用斜杠（/）计算的实例

选中 C1 单元格，输入公式 =A1/B1，按回车，返回 20.83；再次选中 C1，同样用双击 C1 的单元格填充柄的方法求剩余数值相除的结果；操作过程步骤，如图6所示：

图6

提示：在默认情况下，Excel除法计算结果会保留多位小数，如果要保留两位小数，可以按 Ctrl + 1（需要关闭中文输入法），打开“设置单元格格式”窗口，选择“数字”选项卡，再选择左边的“数值”，然后在右边“小数位数”右边输入 2，单击“确定”即可。

五、Excel用一个数字乘或除表格中的所有数

（一）用一个数字乘表格中的所有数

假如要给表格中所有销量乘 0.2。选中 E2 单元格，输入 0.2，单击一下 E3，退出输入状态，再次选中 E2，按 Ctrl + C 复制；框选D2:D7，右键它们，在弹出的菜单中选择“选择性粘贴”，在打开的窗口中，选择“运算”下的“乘”，单击“确定”，则表格中所有销量都乘了 0.2；操作过程步骤，如图7所示：

图7

（二）用一个数字除表格中的所有数

假如要求把表格中的全部销量都除以 2。选中 E2，输入 2，按回车， 退出输入状态，再选中 E2，按 Ctrl + C 复制；框选 D2:D7 并右键它们，然后选择“选择性粘贴”，在打开的窗口中，选择“运算”下面的“除”，点击“确定”，则 D 列全部销量都除了 2；操作过程步骤，如图8所示：

图8

六、Excel乘法函数Product函数的扩展应用实例

（一）If + Product函数组合实现按条件提价

1、假如要给水果价格低于 5 元的提价 10%。双击 E2 单元格，把公式 =IF(C2<5,PRODUCT(C2,(1+10%)),C2) 复制到 E2，按回车，返回 5，由于 5 不满足条件，因此未提价；再次选中 E2，用双击 E2 单元格填充柄的方法把剩余价格提价；操作过程步骤，如图9所示：

图9

2、公式 =IF(C2<5,PRODUCT(C2,(1+10%)),C2) 说明：

A、C2<5 是 If 的条件；如果条件成立，则用 PRODUCT(C2,(1+10%)) 提价 10%，即把 C2 中的数值 5 乘 (1+10%)；否则返回 C2；由于C2 为 5，不满足条件，因此返回 5。

B、当公式在 C3 时，C3 < 5 成立，C3 为 3，因此返回 PRODUCT(C3,(1+10%)) 的计算结果，即返回 3.3；其它的以此类推。

3、如果仅要求返回所有提过价的价格，可以用这个公式 =PRODUCT(IF(C2<5,C2,0),1+10%)，演示如图10所示：

图10

（二）数组指数运算与引用单元格指数运算

1、数组指数运算；双击 B2 单元格，把公式 =PRODUCT({5,3}^{1,-1}) 复制到 B2，按回车，返回 1.666666667。引用单元格指数运算；双击 C2，把公式 =PRODUCT((A2:A3)^{1,-1}) 复制到 C2，按 Ctrl + Shift + 回车，返回 1.00；操作过程步骤，如图11所示：

图11

2、公式说明：

A、公式 =PRODUCT({5,3}^{1,-1}) 中，共有两个数组，第一个为底数数组，第二个为指数数组；计算时，第一次从底数数组中取出 5、从指数数组中取出 1，即计算 5 的 1 次方，结果为 5；第二次从底数数组中取出 3、从指数数组取出 -1，即计算 3 的 -1 次方，也就是 1/3，结果为 0.333333333333333；最后把两次计算的结果相乘，即 5 * 0.333333333333333 等于 1.666666667。

B、公式 =PRODUCT((A2:A3)^{1,-1}) 为数组公式，因此要按 Ctrl + Shift + 回车；A2:A3 以数组形式返回 A2 和 A3 中的数值，即{5;3}，则公式变为 =PRODUCT({5;3}^{1,-1})，与直接把数组 {5,3} 写到公式中一样，但计算方法不一样，计算时，第一次从底数数组中取出 5，再从指数数组中取出 1 和 -1，然后计算 5 的 1 次方和 -1 次方，结果为 5 和 0.2；第二次从底数数组中取出 3，同样再从指数数组中取出 1 和 -1，然后计算 3 的 1 次方和 -1 次方，结果为 3 和 0.333333333333333；则公式变为 =PRODUCT({5,0.2;3,0.333333333333333})，最后把数组中的所有元素相乘，结果为 1。