Excel减法函数用法的7个实例，含带条件、数字带单位、有标识才相减和用表格所有数减一个数

在 Excel 中，计算减法有两种方法，一种是用加法函数（即求和函数）Sum 计算，另一种是用减号计算。用Sum函数计算减法时，只需在减数前加减号；用减号计算直接用一个数减另一个数即可。

在计算减法过程中，如果遇到带条件的减法，需要用If函数来判断条件；如果遇到参与运算的数字带单位，需要用Left函数和Find函数来截取数字，然后再计算；如果要求有标识的数字才参与计算，则需要结合 Indirect + Match + Row 函数实现；如果要求用表格中的所有数减一个数，则需要用选择性粘贴。

一、Excel减法函数说明

Excel 并未直接提供减法函数，减法运算需要使用加法运算函数，即求和函数 Sum，所不同的是只需在要减掉的数前加减号（负号）。另外，除可用Sum函数做减法运算外，还可以直接用减号（即 -）。

二、Excel减法函数的使用方法及实例

（一）两个数求差的实例

1、假如要把 B 列的数字减掉 A 列的数字。双击 C1 单元格，把公式 =SUM(-A1,B1) 复制到 C1，按回车，返回 201；选中 C1，把鼠标移到 C1 右下角的单元格填充柄上，鼠标变为黑色加号后，双击左键，则求出剩余数字之差；操作过程步骤，如图1所示：

图1

2、说明：

公式 =SUM(-A1,B1) 中，A1 前的 - 表示减 A1，公式的意思是：用 B1 减 A1，即用Sum函数计算减法只需在减数前加减号（负号）。

（二）相减结果为负数加绝对值转为正数的实例

1、假如要用 A 列的数字减 B 列的数字，A 列数字小，B 列数字大。双击 C1，把公式 =SUM(A1,-B1) 复制到 C1，按回车，返回 -201；双击 C1，给公式加返回绝对值函数ABS，则公式变为 =ABS(SUM(A1,-B1))，按回车，返回 201；操作过程步骤，如图2所示：

图2

2、公式说明：

公式 =SUM(A1,-B1) 返回的为负数，如果要求做减法运算后返回正数，只需再加一个取绝对值函数ABS。

.

三、用减号计算减法的实例

1、选中 C1 单元格，输入公式 =B1-A1，按回车，返回 201；选中 C2，输入公式 =A2-B2，按回车，返回 -326，双击 C2，给公式加上取绝对值函数 ABS，则公式变为 =ABS(A2-B2)，按回车，返回 326；操作过程步骤，如图3所示：

图3

2、公式说明：

用减号计算减法直接用一个数减另一个数即可，如果所得结果为负数且要求返回正数，同样加取绝对值函数 ABS。

四、Excel减法函数或用减号计算的扩展应用实例

（一）数字带单位的减法运算

1、假如要计算1月与2月销量之差，且1月销量带单位。双击 C2 单元格，把公式 =LEFT(A2,FIND("斤",A2)-1)-B2 复制到 C2，按回车，返回 9；选中 C2，用双击 C2 单元格填充柄的方法求剩余销量之差；操作过程步骤，如图4所示：

图4

2、公式 =LEFT(A2,FIND("斤",A2)-1)-B2 说明：

A、FIND("斤",A2) 用于找“斤”在 A2 中的位置，结果为 4，以把它作为下一步只提取数字的字符个数。之所以要用Find函数返回要提取的数字个数，是因为 A 列不同单元格数字个数不一样，而数字后都有“斤”字，只要返回“斤”字在文本中的位置再减 1，就能准确的计算得数字个数。

B、则 LEFT(A2,FIND("斤",A2)-1) 变为 LEFT(A2,4-1)，进一步计算，用 Left 从 A2 的左边开始截取三个字符，结果为 995。

C、则公式变为 =995-B2，B2 为 986，两数相减，结果为 9。

（二）带条件的减法运算

1、要求：如果 B2 不为空，用 A2 减 B2；否则如果 C2 不为空，用 A2 减 C2；否则如果 D2 不为空，用 A2 减 D2；否则返回空文本。双击 E2 单元格，把公式 =IF(B2<>"",A2-B2,IF(C2<>"",A2-C2,IF(D2<>"",A2-D2,""))) 复制到 E2，按回车，返回 3；选中 E2，双击 E2 的单元格填充柄，则返回剩余数值的结果；操作过程步骤，如图5所示：

图5

2、公式 =IF(B2<>"",A2-B2,IF(C2<>"",A2-C2,IF(D2<>"",A2-D2,""))) 说明：

A、公式嵌套了两个 If，执行时先从最外层的 If 开始，第一次取最外层 If 的条件 B2<>"" 来判断，如果成立（即 B2 不为空），则执行 A2-B2，否则执行 IF(C2<>"",A2-C2,IF(D2<>"",A2-D2,""))；因为 B2 为 6 不空为，因此执行  A2-B2，即 9-6。

B、当公式在 E3 时，则公式变为 =IF(B3<>"",A3-B3,IF(C3<>"",A3-C3,IF(D3<>"",A3-D3,"")))，由于 B3 为空，因此执行 IF(C3<>"",A3-C3,IF(D3<>"",A3-D3,""))；C3 为 4，因此 C3<>"" 成立，执行 A3-C3，即 6-4。

C、当公式在 E4 时，则公式变为 =IF(B4<>"",A4-B4,IF(C4<>"",A4-C4,IF(D4<>"",A4-D4,"")))，由于 B4、C4 和 D4 都为空，因此三个If 的条件没有一个成立，最后返回最里层 If 的第三个参数，即返回 ""。

（三）一列中有标识的数字才相减

1、假如要求 B 列有 1 的 A 列的两数字才相减，例如：B2 和 B4 都有 1，则用 A2 减 A4。双击 C2 单元格，把公式 =IFERROR(A2-INDIRECT("A"&(ROW()+MATCH(B2,B3:B$9,0))),"") 复制到 C2，按回车，返回 36；选中 C2，双击 C2 的单元格填充柄，则计算出剩余有标识的两数之差；操作过程步骤，如图6所示：

图6

2、公式 =IFERROR(A2-INDIRECT("A"&(ROW()+MATCH(B2,B3:B$9,0))),"") 说明：

A、ROW() 用于返回公式所在行的行号，当公式在 C2，它返回 2。

B、MATCH(B2,B3:B$9,0) 用于返回 B2 下离 B2 最近的标识（即 1）的位置，结果为 2；B2 为查找值，B3:B$9 为查找范围，0 表示精确匹配；B2 和 B3 为相对引用，当往下拖时，B2 会变为 B3、B4 等，B3 会变为 B4、B5 等；B$9 表示对列相对引用对行绝对引用，当往下拖时，B$9 不会变为 B10、B11 等；之所以要用 B3:B$9，是因为要实现始终在当前单元格的下一个单元格到最后一个单元格的范围内查找标识。

C、则 INDIRECT("A"&(ROW()+MATCH(B2,B3:B$9,0)) 变为 INDIRECT("A"&(2+2))，进一步计算变为 INDIRECT("A4")，接着再用 Indirect  返回对字符串 "A4" 的引用，即返回 23。

D、则公式变为 =IFERROR(A2-23,"")，A2 为 59，A2-23 等于 36；IfError 是错误处理函数，如果 A2-23 返回错误，IfError 返回 ""，否则返回 A2-23。

（四）用表格中所有的数减一个数

1、假如要用表格中所有数字减掉 100。选中 F2 单元格，输入 100，按回车，再次选中 F2，按 Ctrl + C 复制，框选 B2:E9，右键选中的区域，在弹出的菜单中选择“选择性粘贴”，打开“选择性粘贴”窗口，选择“粘贴”下面的“数值”，再选择“运算”下的“减”，单击“确定”，则表格中的所有数字都减掉 100；操作过程步骤，如图7所示：

图7

2、如果选择“粘贴”下的“全部”，则会把 100 所在的 F2 单元格的格式一起粘贴到 B2:E9，也就是用 F2 的格式覆盖掉 B2:E9 的格式，但选择“数值”，则只粘贴数值不会覆盖格式。